0

I would like to read data from an electronic device that sends data to my PC by UDP. I have programmed a UDP server in Delphi. An exception occurs in class EIdSocketError (Failure #10049). Here is my code:

procedure TForm1.Button1Click(Sender: TObject);
begin
   IdUDPServer1.Bindings.add.IP := '192.168.1.1';  //Electronic device ip
   IdUDPServer1.Bindings.add.Port:= 49152;         //Electronic device port   
   IdUDPServer1.OnUDPRead:= UDPRead;
   IdUDPServer1.Active:=True;

end;

procedure TForm1.UDPRead (Sender: TObject; AData: TStream; ABinding: TIdSocketHandle);
var
   bytes_received: integer;
begin
   bytes_received:=AData.size;
end;

What am I doing wrong?

Thanks in advance

user1361263
  • 101
  • 2
  • 5
  • 11
  • 4
    I think you need to assign the result of IdUDPServer1.Bindings.add to a variable and then set its IP and Port. If I remember correctly what you are doing is adding two bindings, one with IP and one with Port. – Keith Miller May 14 '12 at 14:46
  • I have changed the code as follow, but the error is the same... I am supposing that binding ip must be the ip of the electronic device (not the PC ip): ***var myaddress:TIdSocketHandle; begin myaddress:=IdUDPServer1.Bindings.Add; myaddress.IP:= '192.168.1.1'; myaddress.Port:=49152; IdUDPServer1.Bindings.Add.IP:=myaddress.IP; IdUDPServer1.Bindings.Add.Port:=myaddress.Port; end;*** – user1361263 May 14 '12 at 15:24
  • 2
    No, with Bindings you can specify on which ethernet adapter you are listening for UDP packets. – whosrdaddy May 14 '12 at 16:17
  • I have changed the bind ip address to '0.0.0.0' (and also '127.0.0.1'), but I continue receiving no data from the external device... Is there any bug in my code? – user1361263 May 14 '12 at 17:01
  • 1
    Please update your question with the latest code you are using. – Remy Lebeau May 14 '12 at 19:56

1 Answers1

8

As Keith Miller stated, you are misusing the Bindings property. You are adding 2 bindings to the server - one for 192.168.1.1 on port 0 and another for 0.0.0.0 on port 49152. You need to call Bindings.Add() only once for each IP/Port pair you want to bind to, eg:

var
  Binding: TIdSocketHandle

Binding := IdUDPServer1.Bindings.Add;
Binding.IP := ...;
Binding.Port := ...;

Or:

with IdUDPServer1.Bindings.Add do
begin
  IP := ...;
  Port := ...;
end;

If you set the DefaultPort property ahead of time, then you can simplify the above to this:

IdUDPServer1.DefaultPort := ...;
IdUDPServer1.Bindings.Add.IP := ...;

With that said, socket error 10049 is WSAEADDRNOTAVAIL, which means you are using the wrong IP address in the first place. You need to specify an IP that belongs to the PC that TIdUDPServer is running on - the IP that the device will be sending UDP packets to. You can either bind to the single wildcard IP 0.0.0.0 (or just a blank string ''), which tells TIdUDPServer to bind to all available local IPs:

IdUDPServer1.DefaultPort := ...;
IdUDPServer1.Bindings.Add.IP := ''; // or: '0.0.0.0'

Or you can use Indy's GStack.LocalAddresses property to determine the locally available IPs and create separate Bindings for them individually as needed.

IdUDPServer1.Bindings.Clear;
IdUDPServer1.DefaultPort := ...;

with GStack.LocalAddresses do
begin
  for I := 0 to Count-1 do
    IdUDPServer1.Bindings.Add.IP := Strings[I];
end;

Update: if you bind the server to port 0 to let the OS pick a port, you can discover what port was selected by looking at the TIdSocketHandle.Port property after the server was activated:

var
  Binding: TIdSocketHandle
  ListeningPort: TIdPort;

IdUDPServer1.Bindings.Clear;

Binding := IdUDPServer1.Bindings.Add;
Binding.IP := ...;
Binding.Port := 0;
{
or: 
IdUDPServer1.DefaultPort := 0;
Binding := IdUDPServer1.Bindings.Add;
Binding.IP := ...;
}

IdUDPServer1.Active := True;

ListeningPort := Binding.Port;
Remy Lebeau
  • 555,201
  • 31
  • 458
  • 770