I have been asked to find a Galois extension $K/F$ such that $Gal(K/F)=D_{10}$, a dihedral group of order $10$. I already found an example from Galois group of $X^5 - X^3 - 2X^2 - 2X - 1$ over $\mathbb{Q}$. but I hope to find a systematical way to find such an extension. Would there be any fo such systematical way?
Asked
Active
Viewed 374 times
1 Answers
1
Here are some examples, constructed based on [Polynomials with $D_p$ as Galois group, Christian Jensen, Noriko Yui, Journal of Number Theory 15, 1982, pp. 347-375] .
sciencedirect link to the article
Some computer algebra system is used, sage, since the Galois groups have a slightly more complicated nature.
(If this is not what you want and/or need, please ignore this answer. I am myself not happy with the form of the answer, but it is hard to complement in an other way the paper by Jensen & Yui, and i am somehow happy with the link, and the explicit number theoretical examples.)
Also, typing is partially covered by sage. It was the only way for me to give examples that illustrate Theorem II.1.2 from loc. cit., which reads for a prime congruent to one modulo four:
Let $f= f(x)\in\Bbb Q[x]$ be a monic polynomial of prime degree $p\equiv 1$ modulo four. Then necessary and sufficient conditions for the Galois group of $f$ to be $\cong D_p$ (dihedral group with $2p$ elements) are:
(1) $f$ is irreducible in $\Bbb Q[x]$.
(2) $f$ has a discriminant which is a perfect square.
(3) $f$ has $p$ roots, $a_1,\dots.a_p$, say. We consider the polynomial $g$ with roots $(a_i+a_j)$ for all $\binom p2$ choices of $\{i,j\}$ subset with two elements of $\{1,2,\dots,p\}$. Then $g$ is a product of $(p-1)/2$ irreducible polynomials of degree $p$.
We consider some quadratic imaginary extension $K=\Bbb Q(\sqrt D)$ of $\Bbb Q$ with class number five. Here are some possible values for $D$: $$ -47 \ ,\ -79 \ ,\ -103 \ ,\ -127 \ ,\ -131 \ ,\ -179 \ . $$ These values were obtained from sage with:
sage: [ D for D in range(-1, -200, -1)
....: if ZZ(D).is_squarefree()
....: and QuadraticField(D, names='a').class_number() == 5 ]
[-47, -79, -103, -127, -131, -179]
sage:
Let us experiment with them.
For $D=-47$ we may proceed shortly as follows, we associate $K=\Bbb Q(\sqrt{-47})$, generated by $a=\sqrt{-47}$, then associate (request) its Hilbert class field $H$, generated by some element $b\in H$ over $K$, then ask for the minimal polynomial of $b$:
sage: K.<a> = QuadraticField(-47)
sage: H.<b> = K.hilbert_class_field()
sage: b.minpoly()
x^5 + 2*x^4 + 2*x^3 + x^2 - 1
sage: H.galois_group()
Galois group PARI group [10, -1, 2, "D(10)=5:2"]
of degree 10 of the Number Field in b
with defining polynomial x^5 + 2*x^4 + 2*x^3 + x^2 - 1 over its base field
(Output was manually rearranged.)
We obtain the reciprocal polynomial of the one referenced in the OP. Alternatively, starting from the polynomial:
sage: R.<x> = PolynomialRing(QQ)
sage: f = x^5 - x^3 - 2*x^2 - 2*x - 1
sage: G = f.galois_group()
sage: G.structure_description()
'D5'
(and one can investigate the objects closer in sage).
Note that $H$ is considered above as an extension of $K=\Bbb Q(\sqrt{-47})$. To have the extension over $\Bbb Q$ we may have to ask for
sage: L.<c> = H.absolute_field()
sage: c.minpoly()
x^10 + 4*x^9 + 243*x^8 + 762*x^7 + 23226*x^6 + 54052*x^5 + 1091995*x^4 + 1693406*x^3 + 25247881*x^2 + 19713680*x + 229338475
I would like to check the conditions (1), (2), (3) of the cited theorem:
sage: R.<x> = PolynomialRing(QQ)
sage: f = x^5 - x^3 - 2*x^2 - 2*x - 1
sage: f.discriminant().factor()
47^2
sage: roots = f.roots(ring=QQbar, multiplicities=False)
sage: g = prod( [ x - roots[j] - roots[k] for j in [0..3] for k in [j+1..4] ] )
sage: g = R(g) # try to pass to rational coefficients
sage: g
x^10 - 3*x^8 - 2*x^7 + 9*x^6 + 15*x^5 - 9*x^4 - 22*x^3 + 17*x + 5
sage: factor(g)
(x^5 - 3*x^3 + x^2 + 7*x + 5) * (x^5 - 3*x^2 + 2*x + 1)
So the discriminant of $f$ is a square, and the associated polynomial $g$ splits as a product of $2=(5-1)/2$ irreducible polynomials of degree five.
Let us do "the same" with the other $D$-values.
sage: K.<a> = QuadraticField(-79)
sage: H.<b> = K.hilbert_class_field()
sage: b.minpoly()
x^5 - 2*x^4 + 3*x^3 - 2*x + 1
sage: K.hilbert_class_field_defining_polynomial()
x^5 - 2*x^4 + 3*x^3 - 2*x + 1
sage: H.galois_group()
Galois group PARI group [10, -1, 2, "D(10)=5:2"] of degree 10 of the Number Field in b with defining polynomial x^5 - 2*x^4 + 3*x^3 - 2*x + 1 over its base field
sage: L.<c> = H.absolute_field()
sage: c.minpoly()
x^10 - 4*x^9 + 405*x^8 - 1276*x^7 + 64627*x^6 - 152618*x^5 + 5083871*x^4 - 8116138*x^3 + 197017788*x^2 - 161805592*x + 3001671677
and now we print only the defining polynomials of degree five:
sage: for D in range(-1, -1000, -1):
....: if not ZZ(D).is_squarefree(): continue
....: K.<a> = QuadraticField(D)
....: if K.class_number() != 5: continue
....: f = K.hilbert_class_field_defining_polynomial()
....: print "D = %4s and f = %-43s with disc(f) = %s" % (D, f, f.discriminant().factor())
....:
....:
D = -47 and f = x^5 + 2*x^4 + 2*x^3 + x^2 - 1 with disc(f) = 47^2
D = -79 and f = x^5 - 2*x^4 + 3*x^3 - 2*x + 1 with disc(f) = 79^2
D = -103 and f = x^5 + 3*x^4 + 5*x^3 + 4*x^2 + x + 1 with disc(f) = 103^2
D = -127 and f = x^5 - 4*x^4 + 4*x^3 + x^2 - 1 with disc(f) = 127^2
D = -131 and f = x^5 + x^4 - x^3 - 3*x^2 + 5*x - 1 with disc(f) = 2^4 * 131^2
D = -179 and f = x^5 - 3*x^4 + 7*x^3 + x^2 - 3*x - 1 with disc(f) = 2^4 * 179^2
D = -227 and f = x^5 + 7*x^4 + 15*x^3 + 7*x^2 + x + 1 with disc(f) = 2^4 * 227^2
D = -347 and f = x^5 + 9*x^4 + 25*x^3 + 17*x^2 - 7*x + 1 with disc(f) = 2^4 * 347^2
D = -443 and f = x^5 + 5*x^4 + 7*x^3 - 47*x^2 + 13*x - 1 with disc(f) = 2^4 * 23^2 * 443^2
D = -523 and f = x^5 - 14*x^4 + 49*x^3 + 65*x^2 - 6*x + 1 with disc(f) = 2^6 * 5^6 * 523^2
D = -571 and f = x^5 - 7*x^4 + 75*x^3 - 99*x^2 + 13*x - 1 with disc(f) = 2^4 * 7^2 * 67^2 * 571^2
D = -619 and f = x^5 - 16*x^4 + 113*x^3 - 83*x^2 + 2*x - 1 with disc(f) = 2^6 * 3^6 * 13^2 * 619^2
D = -683 and f = x^5 - 56*x^4 + 41*x^3 + 5*x^2 - 6*x - 1 with disc(f) = 2^6 * 7^2 * 683^2
D = -691 and f = x^5 - 22*x^4 + 119*x^3 + 113*x^2 + 4*x + 1 with disc(f) = 2^6 * 3^6 * 13^2 * 691^2
D = -739 and f = x^5 + 23*x^4 + 167*x^3 + 215*x^2 + 25*x + 1 with disc(f) = 2^4 * 3^12 * 739^2
D = -787 and f = x^5 - 205*x^4 + 33*x^3 - 177*x^2 + 25*x - 1 with disc(f) = 2^4 * 17^2 * 787^2 * 2251^2
D = -947 and f = x^5 + 14*x^4 + 65*x^3 - 425*x^2 - 30*x - 1 with disc(f) = 2^6 * 7^6 * 13^2 * 947^2
Let us also mention:
[Theorem II.3.4, loc. cit.]
Let $f = x^5+ax+b\in\Bbb Q[x]$ be a polynomial. Then its Galois group is $\cong D_5$ iff:
(1) $f$ is irreducible.
(2) $f$ has its discriminant $4^4\cdot b^5+5^5\cdot b^4$ in the rational squares.
(3) The coefficients $a,b$ are of the shape: $$ \begin{aligned} a & = \frac{5^5}{(\lambda-1)^4(\lambda^2-6\lambda+25)}\cdot\lambda\; \mu^4\ ,\\ b & = \frac{5^5}{(\lambda-1)^4(\lambda^2-6\lambda+25)}\cdot\lambda\; \mu^5\ , \end{aligned} $$ with $\lambda,\mu\in\Bbb Q$, $\lambda\ne 1$, $\mu\ne 0$.
In loc. cit. there are some numerical examples. Here is one of them. We take $\lambda = 11$, and $\mu=4$. We obtain $$ f = x^5+11x+44\ . $$ Its discriminant is a square, and the corresponding $g$ is a product of two prime polynomials of degree five:
sage: R.<x> = PolynomialRing(QQ)
sage: f = x^5 + 11*x + 44
sage: f.disc().factor()
2^14 * 7^2 * 11^4
sage: roots = f.roots( ring=QQbar, multiplicities=0)
sage: g = R( prod( [ x - roots[j] - roots[k] for j in [0..3] for k in [j+1..4] ] ) ).factor()
sage: g
(x^5 - 11*x^3 - 22*x^2 + 66*x - 44) * (x^5 + 11*x^3 + 22*x^2 + 22*x + 44)
I have to submit here...
