What is the number of set partitions of $\{1,1,2,2,3,3\}$?

Question

It must be less than $B_6$ (where $B_6$ is the Bell number of $6$) since the elements are "duplicated". I would most appreciate a generating function that gives the number of set partitions of $\{1,1,2,2, ...n,n\}$.

Answer 1

Using the hint given in the OEIS entry we can write an optimized program that makes it possible to compute the sequence in question even for large values of $n$ for example this segment:

$$2, 9, 66, 712, 10457, 198091, 4659138, 132315780, 4441561814, \\ 173290498279, 7751828612725,393110572846777, 22385579339430539, \\ 1419799938299929267, 99593312799819072788, \ldots $$

The aforementioned hint says that we can equivalently count multigraphs with $n$ labeled edges where the vertices of the graph represent the multisets of the multiset partition and are connected by an edge $k$ if the two instances of the value $k$ are included in the sets represented by the two vertices that constitute the edge.

Supposing that we have the cycle index $Z(G_n)$ of the action on the edges of the symmetric group permuting the $n$ vertices of a graph where loops are allowed the desired value is thus given by ($2n$ is the maximum number of vertices we can cover with the $n$ labeled edges and these are multi-edges so they may be labeled with any subset of the $n$ labels)

$$[B_1 B_2 \cdots B_n] Z(G_{2n}) \left(\prod_{q=1}^n (1+B_q)\right).$$

But this cycle index is easy to compute with the computation being documented at this MSE link.

Observe that we have a special case here that admits radical simplification. Suppose we have a term $\alpha\in Z(G_{2n})$ which has the form $$p(\alpha) \prod_k a_k^{j_k(\alpha)}$$

with $p(\alpha)$ being the leading coefficient (a number) and $j_k(\alpha)$ the degree of $a_k$ in $\alpha.$

Now we have that any possible factors $a_k$ where $k\gt 1$ only contribute through the constant term because we are extracting the product $B_1 B_2\cdots B_n.$ This leaves $$p(\alpha) a_1^{j_1(\alpha)}.$$

Finally observe that $$[B_1 B_2\cdots B_n] \left(\prod_{q=1}^n (1+B_q)\right)^{j_1(\alpha)} \\ = [B_1 B_2\cdots B_n] \prod_{q=1}^n (1+B_q)^{j_1(\alpha)} = \prod_{q=1}^n {j_1(\alpha)\choose 1} = j_1(\alpha)^n.$$

The key effect here is that we have eliminated costly exponentiations of multivariate polynomials and are only working with numbers, computing this value: $$\sum_{\alpha\in Z(G_{2n})} p(\alpha) j_1(\alpha)^n.$$

This is the code:

pet_cycleind_symm :=
proc(n)
local p, s;
option remember;

    if n=0 then return 1; fi;

    expand(1/n*add(a[l]*pet_cycleind_symm(n-l), l=1..n));
end;

pet_flatten_term :=
proc(varp)
local terml, d, cf, v;

    terml := [];

    cf := varp;
    for v in indets(varp) do
        d := degree(varp, v);
        terml := [op(terml), seq(v, k=1..d)];
        cf := cf/v^d;
    od;

    [cf, terml];
end;


pet_cycleind_edg :=
proc(n)
option remember;
local s, t, res, cycs, l1, l2, flat, u, v;

    if n=0 then return 1; fi;

    s := 0:
    for t in pet_cycleind_symm(n) do
        flat := pet_flatten_term(t);

        cycs := flat[2]; res := 1;

        for u to nops(cycs) do
            for v from u+1 to nops(cycs) do
                l1 := op(1, cycs[u]); l2 := op(1, cycs[v]);
                res := res * a[lcm(l1, l2)]^(l1*l2/lcm(l1, l2));
            od;
        od;

        for u to nops(cycs) do
            l1 := op(1, cycs[u]);
            if type(l1, odd) then
                # a[l1]^(1/2*l1*(l1-1)/l1);
                res := res*a[l1]^(1/2*(l1-1));
            else
                # a[l1/2]^(l1/2/(l1/2))*a[l1]^(1/2*l1*(l1-2)/l1)
                res := res*a[l1/2]*a[l1]^(1/2*(l1-2));
            fi;
        od;

        s := s + res*t;
    od;

    s;
end;



Q :=
proc(n)
option remember;
    local res, flat, term;

    res := 0;
    for term in pet_cycleind_edg(2*n) do
        flat := pet_flatten_term(term);
        res := res + flat[1]*degree(term, a[1])^n;
    od;

    res;
end;