Is there an analytic solution for this Fokker-Planck equation?

Question

The Fokker-Planck equation for a probability distribution $P(\theta,t)$: \begin{align} \frac{\partial P(\theta,t)}{\partial t}=-\frac{\partial}{\partial\theta}\Big[[\sin(k\theta)+f]P(\theta,t)-D\frac{\partial P(\theta,t)}{\partial\theta}\Big]. \end{align} where $f$, $k$, $D$ are constants, and the initial distribution is a delta function.

Answer 1

Allow me to rewrite the PDE in question in my own notation. We are seeking to solve: \begin{equation} \frac{\partial }{\partial t} P(x,t) = -\frac{\partial}{\partial x}\left[\left(\sin(k x) + F \right) P(x,t)\right] + \frac{\partial ^2}{\partial x^2} \left[D \cdot P(x,t)\right] \end{equation} where $D$, $F$ and $k$ are constants.

By using separation of variables we assume $P(x,t) = X(x) \cdot T(t)$ we get $T(t) = \exp(-E \cdot t)$ and we end up with a following 2nd order ODE for the spatial part of the function $X(x)$. We have: \begin{equation} E \cdot X(x) -\frac{d}{d x}\left[\left(\sin(k x) + F \right) X(x)\right] + \frac{d^2}{d x^2} \left[D \cdot X(x)\right] = 0 \quad (i) \end{equation}

Below I am going to show that equation $(i)$ maps onto the doubly confluent Heun equation.

The first thing we do we take $f(x) := 1/(\imath k) \log(x)$ and we change variables.

\begin{eqnarray} x &\rightarrow& f(x)\\ \frac{d}{d x} &\rightarrow& \frac{1}{f^{'}(x)} \frac{d}{d x}\\ \frac{d^2}{d x^2} &\rightarrow& -\frac{f^{''}(x)}{[f^{'}(x)]^3} \frac{d}{ d x} + \frac{1}{[f^{'}(x)]^2} \frac{d^2}{d x^2} \end{eqnarray}

This results in the following ODE. We have: \begin{equation} \frac{X(x) \left(-2 E x+k x^2+k\right)}{2 D k^2 x^3}+\frac{X'(x) \left(2 D k x+2 i F x+x^2-1\right)}{2 D k x^2}+X''(x)=0 \quad (ii) \end{equation}

Now we eliminate the coefficient at the first derivative. This means we define \begin{equation} m(x):= \exp\left\{-\frac{2 \log (x) (D k+i F)+x+\frac{1}{x}}{4D k}\right\} \end{equation}

and we write $X(x) = m(x) \cdot v(x)$. This results in the following ODE for the function $v(x)$. We define: \begin{eqnarray} (b,a,a_0,a_1,a_2):=\left\{ -\frac{1}{16 D^2 k^2},-\frac{1}{16 D^2 k^2},\frac{D k+i F}{4 D^2 k^2},\frac{1}{8} \left(\frac{-8 D E+2 F^2+1}{D^2 k^2}+2\right),\frac{D k-i F}{4 D^2 k^2} \right\} \end{eqnarray}

and we have:

\begin{equation} v''(x)+v(x) \left(\frac{a}{x^4} + \frac{a_0}{x^3} + \frac{a_1}{x^2} + \frac{a_2}{x} + b\right) =0 \quad (iii) \end{equation}

Equation $(iii)$ has already been dealt with in Hunt for exact solutions of second order ordinary differential equations with varying coefficients. .

Indeed if we now define

\begin{equation} m_1(x):=x^{1-\frac{\imath a_0}{2 \sqrt{a}}} e^{i \left(\frac{\sqrt{a}}{x}+\sqrt{b} x\right)} \end{equation} write $v(x):= m_1(x) \cdot w(x)$ and then in the resulting equation for the function $w(x)$ change the abscissa by $x \rightarrow 1/(2 \imath \sqrt{b}) \cdot x$ then the function $w(x)$ (in the rescaled variable) satisfies the following ODE. We have:

\begin{eqnarray} &&w(x) \left(\frac{-2 E+k \left(1+i D k \sqrt{-\frac{1}{D^2 k^2}}\right) (D k+i F)}{2 D k^2 x^2}+\frac{1+i D k \sqrt{-\frac{1}{D^2 k^2}}}{x}\right)+\\ &&w'(x) \left(\frac{2+\sqrt{-\frac{1}{D^2 k^2}} (-F+i D k)}{x}-\frac{1}{4 D^2 k^2 x^2}+1\right)+w''(x) = 0 \quad (iv) \end{eqnarray} which is the doubly-confluent Heun equation https://dlmf.nist.gov/31.12 .

The Mathematica code below demonstrates all the steps involved.

Clear[f]; x =.; k =.; Clear[X]; Clear[m]; Clear[v]; Clear[m1]; \
Clear[w]; DD =.; F =.; EE =.;
f[x_] := 1/(I k) Log[x];
subst = {x :> f[x], 
   Derivative[1][X][x] :> 1/f'[x] Derivative[1][X][x], 
   Derivative[2][X][x] :> -f''[x]/(f'[x])^3 Derivative[1][X][x] + 
     1/(f'[x])^2 Derivative[2][X][x]};
myeqn = Collect[
   EE X[x] - D[(Sin[k x] + F) X[x], x] + DD D[X[x], {x, 2}] /. subst /. 
    X[f[x]] :> X[x], {X[x], X'[x], X''[x]}];
myeqn = Collect[
  myeqn/Coefficient[myeqn, X''[x]], {X[x], X'[x], X''[x]}, Simplify]

m[x_] = FullSimplify[Exp[-1/2 Integrate[Coefficient[myeqn, X'[x]], x]]]
X[x_] = m[x] v[x];
myeqn = Collect[(myeqn/m[x]), {v[x], v'[x], v''[x], x}, FullSimplify]

b = Coefficient[Coefficient[myeqn, v[x]], x, 0];
a = Coefficient[Coefficient[myeqn, v[x]], x, -4];
a0 = Coefficient[Coefficient[myeqn, v[x]], x, -3];
a1 = Coefficient[Coefficient[myeqn, v[x]], x, -2];
a2 = Coefficient[Coefficient[myeqn, v[x]], x, -1];

m1[x_] = x^(1 + a0/(2 I Sqrt[a])) Exp[I (Sqrt[a]/x + Sqrt[b] x)];
v[x_] = m1[x] w[x];

myeqn = Collect[
   Simplify[Factor[myeqn]/m1[x]], {w[x], w'[x], w''[x], x^_}, 
   Simplify];

Ab = 1/(2 I Sqrt[b]);
subst = {x :> Ab x, Derivative[1][w][x] :> 1/Ab Derivative[1][w][x], 
   Derivative[2][w][x] :> 1/(Ab)^2 Derivative[2][w][x]};
Collect[Expand[(Ab^2 myeqn)] /. subst /. w[Ab x] :> w[x], {w[x], 
  w'[x], w''[x], x^_}, FullSimplify]

Note: If we assume that both $D>0$ and $k>0$ then equation $(iv)$ simplifies even further and reads: \begin{equation} w'(x) \left(-\frac{1}{4 D^2 k^2 x^2}+\frac{1-\frac{i F}{D k}}{x}+1\right)-\frac{E w(x)}{D k^2 x^2}+w''(x)=0 \end{equation}