Perl Regex 'e' (eval) modifier with s///

Question

I'm having a little trouble comprehending this simple use of the /e regex modifier.

my $var = 'testing';
$_ = 'In this string we are $var the "e" modifier.';

s/(\$\w+)/$1/ee;

print;

Returns: "In this string we are testing the "e" modifier."

I cannot see why two 'e' modifiers are required. As far as I can see, $1 should capture '$var' from the string and a single 'e' modifier should then be able to replace the variable with its value. I must be misunderstanding something however, since trying the above code with just one 'e' modifier does not visibly replace anything in the string.

Excuse me for asking such a simple question!

Thanks.

note that "e" is not a regex modifier, since it does not affect the regex! It only affects the replacement part. So "e" modifies the s/// operator, not the regex. — tadmc, May 21 '11 at 15:16

score 41 · Accepted Answer · edited Aug 03 '15 at 17:44

It’s not exactly a “simple” question, so don’t beat yourself up.

The issue is that with a single /e, the RHS is understood to be code whose eval’d result is used for the replacement.

What is that RHS? It’s $1. If you evaluated $1, you find that contains the string $var. It does not contain the contents of said variable, just $ followed by a v followed by an a followed by an r.

Therefore you must evaluate it twice, once to turn $1 into $var, then again to turn the previous result of $var into the string "testing". You do that by having the double ee modifier on the s operator.

You can check this pretty easily by running it with one /e versus with two of them. Here’s a demo a both, plus a third way that uses symbolic dereferencing — which, because it references the package symbol table, works on package variables only.

use v5.10;

our $str = q(In this string we are $var the "e" modifier.);
our $var = q(testing);

V1: {
    local $_ = $str; 
    s/(\$\w+)/$1/e;
    say "version 1: ", $_;

}

V2: {
    local $_ = $str;
    s/(\$\w+)/$1/ee;
    say "version 2: ", $_;
}

V3: {
    no strict "refs";
    local $_ = $str;
    s/\$(\w+)/$$1/e;
    say "version 3: ", $_;
}

When run, that produces:

version 1: In this string we are $var the "e" modifier.
version 2: In this string we are testing the "e" modifier.
version 3: In this string we are testing the "e" modifier.

That's great, thank you. As a curiosity, why does producing the regex s/(\$\w+)/$1/ with NO modifier still replace it with the captured value ($var)? It seems to me that that is what the first /e is there for? — pb149, May 21 '11 at 14:33
@user761513: With no modifier, `$1` as replacement text is used as a string. With a single `e`, it's used as an expression, with exactly the same outcome. To see the difference, compare `s/…/$1 (hello)/` (a string) with `s/…/uc($1)/e` (an expression). — Gilles 'SO- stop being evil', May 21 '11 at 14:37
Specifically, with no modifier, the replacement text acts like a _double quoted_ string. Hence `$1` interpolates to what was captured by the first set of parenthesis. — pjf, May 21 '11 at 17:39

score 9 · Answer 2 · edited Jan 07 '14 at 00:03

9

To be clear, the s//ee form is not modifying your regex pattern or regex interpretation at all. It is an optional treatment of the replacement side string after the regex is performed. (See PERLOP Regex Quote-like operators)

The e or ee just get mixed into the PATTERN side regex options in the s/PATTERN/REPLACEMENT/msixpodualgcer form.

From Perlop:

Options are as with m// with the addition of the following replacement specific options:
e Evaluate the right side as an expression.
ee  Evaluate the right side as a string then eval the result.
r   Return substitution and leave the original string untouched.

You can see the same e vs ee type behavior in non regex situations, as this example shows:

#!/usr/bin/perl 
use warnings;
use strict;

my $var = "var's contents";
my $str='"-> $var <-"';
print eval('$str'), "\n";        # equivalent to s//e
print eval(eval('$str')), "\n";  # equivalent to s//ee

Output:

"-> $var <-"
-> var's contents <-

edited Jan 07 '14 at 00:03

Bill Ruppert

8,956
7
27
44

answered May 21 '11 at 16:26

the wolf

34,510
13
53
71

1

What does `# use strinct` do? ;-} – dawg May 21 '11 at 18:00
1

[Rejected as an edit] A final note, just for completeness: You can add even more `e`s, it is not because the documentation stops there that it is not doable: my $testing = 'Phew!'; my $var = '$testing'; $_ = 'We are $var the "e" modifier.'; s/(\$\w+)/$1/e; print; $_ = 'We are $var the "e" modifier.'; s/(\$\w+)/$1/ee; print; $_ = 'We are $var the "e" modifier.'; s/(\$\w+)/$1/eee; print; producing We are $var the "e" modifier. We are $testing the "e" modifier. We are Phew! the "e" modifier. – OmarOthman Aug 03 '15 at 19:05
@thewolf Could you please edit your post with my modification? – OmarOthman Aug 11 '15 at 17:25

score -1 · Answer 3 · answered Jun 02 '15 at 01:28

Try the rename utility from the latest perl package with:

rename -v 's/\b(\w)/uc($1)/eg' *

Here, pattern \b find the word boundary, and the e modifier enables evaluation in the substitution, and g replace the all occurrence.

You may also rename to camelCase with:

rename -v 's/\b(\w)/uc($1)/eg' *
rename -v 's/^(\w)/lc($1)/e' *
rename -v 's/\s+//g' *

Perl Regex 'e' (eval) modifier with s///

3 Answers3

Linked